Terbilang Rupiah

Aturan menulis terbilang dalam bahasa Indonesia

Bilangan dibaca per kelompok tiga angka dari kiri — ratusan juta, ratusan ribu, lalu ratusan — dan tiap kelompok diberi nama satuannya: ribu, juta, miliar, triliun. Beberapa aturan kecil yang paling sering membuat orang ragu:

1. Satu di depan belas, puluh, ratus, dan ribu menjadi awalan se-: sebelas, sepuluh, seratus, seribu. Di depan juta, miliar, dan triliun tetap ditulis satu: satu juta, satu miliar.
2. Belasan untuk 12–19 ditulis terpisah: dua belas, sembilan belas. Hanya 10 dan 11 yang punya bentuk sendiri.
3. Kelompok yang isinya nol dilewati, tidak dibaca. 1.000.500 adalah satu juta lima ratus, bukan satu juta nol ribu lima ratus.
4. Seribu hanya untuk satu ribu yang berdiri sendiri. 101.000 adalah seratus satu ribu, karena yang dikalikan ribu adalah 101, bukan 1.
5. Ejaan baku menurut KBBI adalah miliar dan triliun, bukan milyar dan trilyun.

Contoh terbilang nominal yang sering dipakai

Menulis terbilang di kwitansi, cek, dan bilyet giro

Di kwitansi, terbilang ditulis di baris "Uang sejumlah" atau "Terbilang", biasanya dengan huruf awal kapital tiap kata dan diakhiri kata rupiah: Satu Juta Dua Ratus Lima Puluh Ribu Rupiah. Nominal angkanya ditulis di kotak terpisah, misalnya Rp1.250.000,-.

Tanda pagar (# … #) atau garis di sisa baris kosong dipakai supaya tidak ada kata yang bisa diselipkan setelah kwitansi diserahkan. Pagar ditutup tepat setelah kata rupiah.

Di cek, jumlah dalam huruf punya kedudukan yang lebih kuat: bila tulisan huruf dan angka berbeda, Pasal 179 KUHD menetapkan jumlah yang ditulis dengan huruf yang berlaku. Di cek maupun bilyet giro, bank biasanya menolak lembar yang nominalnya dicoret atau ditimpa. Kalau salah tulis, batalkan lembarnya dan tulis lembar baru.

Membuat fungsi terbilang di Excel

Excel tidak punya fungsi terbilang bawaan. Cara paling praktis adalah menambahkan fungsi sendiri lewat VBA: tekan Alt + F11, pilih Insert → Module, tempel kode berikut, lalu simpan file sebagai .xlsm.

Function Terbilang(ByVal n As Double) As String
    Dim s, r As String
    s = Array("", "satu", "dua", "tiga", "empat", "lima", "enam", _
              "tujuh", "delapan", "sembilan", "sepuluh", "sebelas")
    n = Int(n)
    If n < 12 Then
        r = s(n)
    ElseIf n < 20 Then
        r = Terbilang(n - 10) & " belas"
    ElseIf n < 100 Then
        r = Terbilang(n \ 10) & " puluh " & Terbilang(n Mod 10)
    ElseIf n < 200 Then
        r = "seratus " & Terbilang(n - 100)
    ElseIf n < 1000 Then
        r = Terbilang(n \ 100) & " ratus " & Terbilang(n Mod 100)
    ElseIf n < 2000 Then
        r = "seribu " & Terbilang(n - 1000)
    ElseIf n < 1000000 Then
        r = Terbilang(n \ 1000) & " ribu " & Terbilang(n Mod 1000)
    ElseIf n < 1000000000 Then
        r = Terbilang(n \ 1000000) & " juta " & Terbilang(n Mod 1000000)
    Else
        r = Terbilang(Int(n / 1000000000)) & " miliar " & _
            Terbilang(n - Int(n / 1000000000) * 1000000000)
    End If
    Terbilang = Trim(r)
End Function

Setelah itu, di sel mana pun cukup tulis =PROPER(Terbilang(A2)&" rupiah") untuk nominal di sel A2. PROPER membuat huruf awal tiap kata kapital; hapus kalau ingin huruf kecil semua.

Fungsi ini menangani bilangan bulat sampai 999.999.999.999 (kurang dari satu triliun) dan mengabaikan sen. Angka nol menghasilkan teks kosong. Google Sheets tidak menjalankan VBA, jadi untuk Sheets salin hasil dari tool di atas.